Vanig - The World’s first integrated E-Commerce and Supply Chain Ecosystem powered by Blockchain.



  • What is Vanig

    Vanig is an e-commerce startup powered by the blockchain. Our aim is to create a platform that changes the way e-commerce works. From manufacturer to consumers, we can apply the power of the blockchain to make shopping an amazing experience for everyone involved.

    The Problem

    The e-commerce industry is at a stage where it is thriving but is yet to achieve its full potential. There are
    several challenges faced today by various e-commerce companies. We at Vanig aim to solve the key issues
    faced by these businesses today, such as:
    • Lack of visibility and transparency of the supply chain.
    • Too many Intermediaries.
    • High transaction fees.
    • Lack of effective tracking mechanisms and recall systems.

    The VANIG Solution

    The e-commerce industry is at a stage where it is thriving but is yet to achieve its full potential. There are
    several challenges faced today by various e-commerce companies. We at Vanig aim to solve the key issues
    faced by these businesses today, such as:
    • Lack of visibility and transparency of the supply chain.
    • Too many Intermediaries.
    • High transaction fees.
    • Lack of effective tracking mechanisms and recall systems.
    Vanig utilizes a proven blockchain technology that has been developed by the world’s largest blockchain
    technology consortium, Hyperledger. Not only does the blockchain drive the transaction, but also records it.
    We can easily scale to seamlessly integrate with major players such as Amazon. We will be able to target a
    lot of issues at the same time, such as:
    • Ensuring transparency at every step on the platform.
    • Reduction in the number of intermediaries on the platform.
    • Generating a more efficient supply chain.
    • Reducing counterfeit items on online platforms.


    Vanig Tokens:

    Vanig tokens will be used to make real-time money transactions and money transfers possible, something
    which is not possible today at any major e-commerce player. Sellers and buyers will also be able to earn
    VANIG tokens for listing, buying, performing various activities on the platform. People can purchase VANIG
    tokens during the Pre-sale or main token sale and help create the e-commerce platform of the future.




    Vanig Smart Contract

    pragma solidity 0.4.23;
    /**
     * @title SafeMath
     * @dev Math operations with safety checks that throw on error
     */
    library SafeMath {
        /**
        * @dev Multiplies two numbers, throws on overflow.
        */
        function mul(uint256 a, uint256 b) internal pure returns (uint256) {
            if (a == 0) {
                return 0;
            }
            uint256 c = a * b;
            assert(c / a == b);
            return c;
        }
        /**
        * @dev Integer division of two numbers, truncating the quotient.
        */
        function div(uint256 a, uint256 b) internal pure returns (uint256) {
            // assert(b > 0); // Solidity automatically throws when dividing by 0
            uint256 c = a / b;
            // assert(a == b * c + a % b); // There is no case in which this doesn't hold
            return c;
        }
        /**
        * @dev Subtracts two numbers, throws on overflow (i.e. if subtrahend is greater than minuend).
        */
        function sub(uint256 a, uint256 b) internal pure returns (uint256) {
            assert(b <= a);
            return a - b;
        }
        /**
        * @dev Adds two numbers, throws on overflow.
        */
        function add(uint256 a, uint256 b) internal pure returns (uint256) {
            uint256 c = a + b;
            assert(c >= a);
            return c;
        }
    }
    /**
     * @title ERC20Basic
     * @dev Simpler version of ERC20 interface
     * @dev see https://github.com/ethereum/EIPs/issues/179
     */
    contract ERC20Basic {
        function totalSupply() public view returns (uint256);
        function balanceOf(address who) public view returns (uint256);
        function transfer(address to, uint256 value) public returns (bool);
        event Transfer(address indexed from, address indexed to, uint256 value);
    }
    /**
     * @title Basic token
     * @dev Basic version of StandardToken, with no allowances.
     */
    contract BasicToken is ERC20Basic {
        using SafeMath for uint256;
        mapping(address => uint256) internal balances;
        uint256 internal totalSupply_;
        /**
        * @dev total number of tokens in existence
        */
        function totalSupply() public view returns (uint256) {
            return totalSupply_;
        }
        /**
        * @dev transfer token for a specified address
        * @param _to The address to transfer to.
        * @param _value The amount to be transferred.
        */
        function transfer(address _to, uint256 _value) public returns (bool) {
            require(_to != address(0));
            require(_value <= balances[msg.sender]);
            // SafeMath.sub will throw if there is not enough balance.
            balances[msg.sender] = balances[msg.sender].sub(_value);
            balances[_to] = balances[_to].add(_value);
            emit Transfer(msg.sender, _to, _value);
            return true;
        }
        /**
        * @dev Gets the balance of the specified address.
        * @param _owner The address to query the the balance of.
        * @return An uint256 representing the amount owned by the passed address.
        */
        function balanceOf(address _owner) public view returns (uint256 balance) {
            return balances[_owner];
        }
    }
    /**
     * @title ERC20 interface
     * @dev see https://github.com/ethereum/EIPs/issues/20
     */
    contract ERC20 is ERC20Basic {
        function allowance(address owner, address spender) public view returns (uint256);
        function transferFrom(address from, address to, uint256 value) public returns (bool);
        function approve(address spender, uint256 value) public returns (bool);
        event Approval(address indexed owner, address indexed spender, uint256 value);
    }
    /**
     * @title Standard ERC20 token
     *
     * @dev Implementation of the basic standard token.
     * @dev https://github.com/ethereum/EIPs/issues/20
     * @dev Based on code by FirstBlood: https://github.com/Firstbloodio/token/blob/master/smart_contract/FirstBloodToken.sol
     */
    contract StandardToken is ERC20, BasicToken {
        mapping (address => mapping (address => uint256)) internal allowed;
        /**
         * @dev Transfer tokens from one address to another
         * @param _from address The address which you want to send tokens from
         * @param _to address The address which you want to transfer to
         * @param _value uint256 the amount of tokens to be transferred
         */
        function transferFrom(address _from, address _to, uint256 _value) public returns (bool) {
            require(_to != address(0));
            require(_value <= balances[_from]);
            require(_value <= allowed[_from][msg.sender]);
            balances[_from] = balances[_from].sub(_value);
            balances[_to] = balances[_to].add(_value);
            allowed[_from][msg.sender] = allowed[_from][msg.sender].sub(_value);
            emit Transfer(_from, _to, _value);
            return true;
        }
        /**
         * @dev Approve the passed address to spend the specified amount of tokens on behalf of msg.sender.
         *
         * Beware that changing an allowance with this method brings the risk that someone may use both the old
         * and the new allowance by unfortunate transaction ordering. One possible solution to mitigate this
         * race condition is to first reduce the spender's allowance to 0 and set the desired value afterwards:
         * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
         * @param _spender The address which will spend the funds.
         * @param _value The amount of tokens to be spent.
         */
        function approve(address _spender, uint256 _value) public returns (bool) {
            allowed[msg.sender][_spender] = _value;
            emit Approval(msg.sender, _spender, _value);
            return true;
        }
        /**
         * @dev Function to check the amount of tokens that an owner allowed to a spender.
         * @param _owner address The address which owns the funds.
         * @param _spender address The address which will spend the funds.
         * @return A uint256 specifying the amount of tokens still available for the spender.
         */
        function allowance(address _owner, address _spender) public view returns (uint256 remaining) {
            return allowed[_owner][_spender];
        }
        /**
         * approve should be called when allowed[_spender] == 0. To increment
         * allowed value is better to use this function to avoid 2 calls (and wait until
         * the first transaction is mined)
         * From MonolithDAO Token.sol
         */
        function increaseApproval (address _spender, uint _addedValue) public returns (bool success) {
            allowed[msg.sender][_spender] = allowed[msg.sender][_spender].add(_addedValue);
            emit Approval(msg.sender, _spender, allowed[msg.sender][_spender]);
            return true;
        }
        function decreaseApproval (address _spender, uint _subtractedValue) public returns (bool success) {
            uint oldValue = allowed[msg.sender][_spender];
            if (_subtractedValue > oldValue) {
                allowed[msg.sender][_spender] = 0;
            } else {
                allowed[msg.sender][_spender] = oldValue.sub(_subtractedValue);
            }
            emit Approval(msg.sender, _spender, allowed[msg.sender][_spender]);
            return true;
        }
    }
    /**
     * @title SafeERC20
     * @dev Wrappers around ERC20 operations that throw on failure.
     * To use this library you can add a `using SafeERC20 for ERC20;` statement to your contract,
     * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
     */
    library SafeERC20 {
        function safeTransfer(ERC20Basic token, address to, uint256 value) internal {
            assert(token.transfer(to, value));
        }
        function safeTransferFrom(ERC20 token, address from, address to, uint256 value) internal {
            assert(token.transferFrom(from, to, value));
        }
        function safeApprove(ERC20 token, address spender, uint256 value) internal {
            assert(token.approve(spender, value));
        }
    }
    /**
     * @title TokenTimelock
     * @dev TokenTimelock is a token holder contract that will allow a
     * beneficiary to extract the tokens after a given release time
     */
    contract TokenTimelock {
        using SafeERC20 for ERC20Basic;
        // ERC20 basic token contract being held
        ERC20Basic public token;
        // beneficiary of tokens after they are released
        address public beneficiary;
        // timestamp when token release is enabled
        uint64 public releaseTime;
        constructor(ERC20Basic _token, address _beneficiary, uint64 _releaseTime) public {
            require(_releaseTime > uint64(block.timestamp));
            token = _token;
            beneficiary = _beneficiary;
            releaseTime = _releaseTime;
        }
        /**
         * @notice Transfers tokens held by timelock to beneficiary.
         */
        function release() public {
            require(uint64(block.timestamp) >= releaseTime);
            uint256 amount = token.balanceOf(this);
            require(amount > 0);
            token.safeTransfer(beneficiary, amount);
        }
    }
    /**
     * @title Burnable Token
     * @dev Token that can be irreversibly burned (destroyed).
     */
    contract BurnableToken is BasicToken {
      event Burn(address indexed burner, uint256 value);
      /**
       * @dev Burns a specific amount of tokens.
       * @param _value The amount of token to be burned.
       */
      function burn(uint256 _value) public {
        _burn(msg.sender, _value);
      }
      function _burn(address _who, uint256 _value) internal {
        require(_value <= balances[_who]);
        // no need to require value <= totalSupply, since that would imply the
        // sender's balance is greater than the totalSupply, which *should* be an assertion failure
        balances[_who] = balances[_who].sub(_value);
        totalSupply_ = totalSupply_.sub(_value);
        emit Burn(_who, _value);
        emit Transfer(_who, address(0), _value);
      }
    }
    /**
     * @title TokenVault
     * @dev TokenVault is a token holder contract that will allow a
     * beneficiary to spend the tokens from some function of a specified ERC20 token
     */
    contract TokenVault {
        using SafeERC20 for ERC20;
        // ERC20 token contract being held
        ERC20 public token;
        constructor(ERC20 _token) public {
            token = _token;
        }
        /**
         * @notice increase the allowance to the full amount of tokens held
         */
        function fillUpAllowance() public {
            uint256 amount = token.balanceOf(this);
            require(amount > 0);
            token.approve(token, amount);
        }
    }
    contract Owned {
        address public owner;
        constructor() public {
            owner = msg.sender;
        }
        modifier onlyOwner {
            require(msg.sender == owner);
            _;
        }
    }
    /**
     * @title TokenVesting
     * @dev A token holder contract that can release its token balance gradually like a
     * typical vesting scheme, with a cliff and vesting period. Optionally revocable by the
     * owner.
     */
    contract TokenVesting is Owned {
        using SafeMath for uint256;
        using SafeERC20 for ERC20Basic;
        event Released(uint256 amount);
        event Revoked();
        // beneficiary of tokens after they are released
        address public beneficiary;
        uint256 public cliff;
        uint256 public start;
        uint256 public duration;
        bool public revocable;
        mapping (address => uint256) public released;
        mapping (address => bool) public revoked;
        /**
         * @dev Creates a vesting contract that vests its balance of any ERC20 token to the
         * _beneficiary, gradually in a linear fashion until _start + _duration. By then all
         * of the balance will have vested.
         * @param _beneficiary address of the beneficiary to whom vested tokens are transferred
         * @param _cliff duration in seconds of the cliff in which tokens will begin to vest
         * @param _duration duration in seconds of the period in which the tokens will vest
         * @param _revocable whether the vesting is revocable or not
         */
        constructor(address _beneficiary, uint256 _start, uint256 _cliff, uint256 _duration, bool _revocable) public {
            require(_beneficiary != address(0));
            require(_cliff <= _duration);
            beneficiary = _beneficiary;
            revocable = _revocable;
            duration = _duration;
            cliff = _start.add(_cliff);
            start = _start;
        }
        /**
         * @notice Transfers vested tokens to beneficiary.
         * @param token ERC20 token which is being vested
         */
        function release(ERC20Basic token) public {
            uint256 unreleased = releasableAmount(token);
            require(unreleased > 0);
            released[token] = released[token].add(unreleased);
            token.safeTransfer(beneficiary, unreleased);
            emit Released(unreleased);
        }
        /**
         * @notice Allows the owner to revoke the vesting. Tokens already vested
         * remain in the contract, the rest are returned to the owner.
         * @param token ERC20 token which is being vested
         */
        function revoke(ERC20Basic token) public onlyOwner {
            require(revocable);
            require(!revoked[token]);
            uint256 balance = token.balanceOf(this);
            uint256 unreleased = releasableAmount(token);
            uint256 refund = balance.sub(unreleased);
            revoked[token] = true;
            token.safeTransfer(owner, refund);
            emit Revoked();
        }
        /**
         * @dev Calculates the amount that has already vested but hasn't been released yet.
         * @param token ERC20 token which is being vested
         */
        function releasableAmount(ERC20Basic token) public view returns (uint256) {
            return vestedAmount(token).sub(released[token]);
        }
        /**
         * @dev Calculates the amount that has already vested.
         * @param token ERC20 token which is being vested
         */
        function vestedAmount(ERC20Basic token) public view returns (uint256) {
            uint256 currentBalance = token.balanceOf(this);
            uint256 totalBalance = currentBalance.add(released[token]);
            if (now < cliff) {
                return 0;
            } else if (now >= start.add(duration) || revoked[token]) {
                return totalBalance;
            } else {
                return totalBalance.mul(now.sub(start)).div(duration);
            }
        }
    }
    contract VanigToken is BurnableToken, Owned {
        string public constant name = "Vanig";
        string public constant symbol = "VANG";
        uint8 public constant decimals = 18;
        /// Maximum tokens to be allocated (300 million)
        uint256 public constant HARD_CAP = 300000000 * 10**uint256(decimals);
        /// The owner of this address will distrbute the locked and vested tokens
        address public vanigAdminAddress;
        /// This vault holds are the Vanig team
        TokenVault public teamTokensVault;
        /// This vault holds the Vanig Incentives tokens
        TokenVault public incentivesTokensVault;
        /// This vault holds the Vanig Advisory tokens
        TokenVault public advisoryTokensVault;
        /// This vault holds Vanig Legal tokens
        TokenVault public legalTokensVault;
        /// Store the vesting contracts addresses
        mapping(address => address) public vestingOf;
        /// This address is used to keep the tokens for sale
        address public saleTokensAddress;
        /// This address is used to keep the Vanig Referral Program
        address public referralsTokensAddress;
        /// when the token sale is closed, the trading is open
        bool public saleClosed = false;
        /// Only allowed to execute before the token sale is closed
        modifier beforeSaleClosed {
            require(!saleClosed);
            _;
        }
        modifier onlyAdmin {
            require(msg.sender == vanigAdminAddress);
            _;
        }
        constructor(address _vanigAdminAddress, address _referralsTokensAddress, address _saleTokensAddress) public {
            require(_vanigAdminAddress != address(0));
            require(_referralsTokensAddress != address(0));
            require(_saleTokensAddress != address(0));
            vanigAdminAddress = _vanigAdminAddress;
            referralsTokensAddress = _referralsTokensAddress;
            saleTokensAddress = _saleTokensAddress;
            /// Maximum tokens to be allocated on the sale
            /// 180M VANG tokens
            uint256 saleTokens = 180000000 * 10**uint256(decimals);
            totalSupply_ = saleTokens;
            balances[saleTokensAddress] = saleTokens;
            /// Referrals Program tokens - 15 million
            uint256 referralsTokens = 15000000 * 10**uint256(decimals);
            totalSupply_ = totalSupply_.add(referralsTokens);
            balances[referralsTokensAddress] = referralsTokens;
        }
        function createVestableTokens() internal onlyOwner {
            {
                /// Team tokens - 54 million
                uint256 teamTokens = 54000000 * 10**uint256(decimals);
                totalSupply_ = totalSupply_.add(teamTokens);
                teamTokensVault = new TokenVault(this);
                balances[teamTokensVault] = teamTokens;
                teamTokensVault.fillUpAllowance();
            }
            {
                /// Incentives tokens - 39 million
                uint256 incentivesTokens = 39000000 * 10**uint256(decimals);
                totalSupply_ = totalSupply_.add(incentivesTokens);
                incentivesTokensVault = new TokenVault(this);
                balances[incentivesTokensVault] = incentivesTokens;
                incentivesTokensVault.fillUpAllowance();
            }
            {
                /// Advisory tokens - 6 million
                uint256 advisoryTokens = 6000000 * 10**uint256(decimals);
                totalSupply_ = totalSupply_.add(advisoryTokens);
                advisoryTokensVault = new TokenVault(this);
                balances[advisoryTokensVault] = advisoryTokens;
                advisoryTokensVault.fillUpAllowance();
            }
            {
                /// Legal tokens - 6 million
                uint256 legalTokens = 6000000 * 10**uint256(decimals);
                totalSupply_ = totalSupply_.add(legalTokens);
                legalTokensVault = new TokenVault(this);
                balances[legalTokensVault] = legalTokens;
                legalTokensVault.fillUpAllowance();
            }
        }
        function vestTokens(address _fromVault, uint256 _tokensAmount, address _beneficiary, uint256 _start,
        uint256 _cliff, uint256 _duration, bool _revocable) external onlyAdmin {
            TokenVesting vesting = TokenVesting(vestingOf[_beneficiary]);
            if(vesting == address(0)) {
                vesting = new TokenVesting(_beneficiary, _start, _cliff, _duration, _revocable);
                vestingOf[_beneficiary] = address(vesting);
            }
            if(this.allowance(_fromVault, address(this)) < _tokensAmount) {
                TokenVault(_fromVault).fillUpAllowance();
            }
            require(this.transferFrom(_fromVault, vesting, _tokensAmount));
        }
        /// @dev check the locked balance of an owner
        function lockedBalanceOf(address _owner) public view returns (uint256) {
            return balances[vestingOf[_owner]];
        }
        /// @dev check the locked but releaseable balance of an owner
        function releaseableBalanceOf(address _owner) public view returns (uint256) {
            return TokenVesting(vestingOf[_owner]).vestedAmount(this);
        }
        /// @dev release all unlocked tokens of an owner
        function releaseTokens(address _owner) public {
            TokenVesting(vestingOf[_owner]).release(this);
        }
        /// @dev get the TokenTimelock contract address for an owner
        function vestingOf(address _owner) public view returns (address) {
            return vestingOf[_owner];
        }
        /// @dev Close the token sale
        function closeSale() public onlyOwner beforeSaleClosed {
            createVestableTokens();
            saleClosed = true;
        }
        /// @dev Trading limited - requires the token sale to have closed
        function transferFrom(address _from, address _to, uint256 _value) public returns (bool) {
            if(saleClosed || msg.sender == vanigAdminAddress) {
                return super.transferFrom(_from, _to, _value);
            }
            return false;
        }
        /// @dev Trading limited - requires the token sale to have closed
        function transfer(address _to, uint256 _value) public returns (bool) {
            if(saleClosed || msg.sender == owner || (msg.sender == saleTokensAddress && _to == owner)) {
                return super.transfer(_to, _value);
            }
            return false;
        }
    }
                
            

    Documents:

    White Paper:https://vanig.io/latest-whitep...

    One pager:https://vanig.io/latest-onepag...

    Business Model:https://vanig.io/business-mode...

    Pitch deck:https://vanig.io/pitch-deck-pd...

    Links:

    website:https://vanig.io

    blog:https://medium.com/vanigplatfo...

    telegram:https://t.me/vanigplatform

    twitter:https://twitter.com/VanigPlatf...

    facbook:https://www.facebook.com/vanig...

    youtube:https://www.youtube.com/c/Vani...

    linkedin:https://www.linkedin.com/compa...

    github:https://github.com/VanigPro/

    reddit:https://www.reddit.com/r/Vanig...




Looks like your connection to Cryptocentral was lost, please wait while we try to reconnect.